RogerBW's Blog

I’ve been doing the Perl Weekly Challenges. The latest involved swapping characters, and generating Gray code.

You are given a string $S of size $N.

You are also given swap count $C and offset $O such that $C >= 1, $O >= 1 and $C + $O <= $N.

Write a script to perform character swapping like below:

$S[ 1 % $N ] <=> $S[ (1 + $O) % $N ] $S[ 2 % $N ] <=> $S[ (2 + $O) % $N ] $S[ 3 % $N ] <=> $S[ (3 + $O) % $N ] ... ... $S[ $C % $N ] <=> $S[ ($C + $O) % $N ]

Why?

Never mind. This could be done by extracting a $C-character substring at point 1 and another at point $O+1 and swapping them, but there are concerns of overlapping. So we might as well simply implement this directly as the problem specifies. There's just the one clever line here.

sub swap {
  my $s=shift;
  my $c=shift;
  my $o=shift;
  my $n=length($s);
  my @s=split '',$s;
  foreach my $ci (1..$c) {
    ($s[$ci % $n],$s[($ci+$o) % $n]) = ($s[($ci+$o) % $n],$s[$ci % $n]);
  }
  return join('',@s);
}

Raku is much the same, except for

  my $n=$s.chars;
  my @s=$s.comb;

You are given an integer 2 <= $N <= 5.

Write a script to generate $N-bit gray code sequence.

After Frank Gray (1887-1969), one of the pioneers of raster scan television.

We'll generate this from a standing start (all right, not quite, though it would work if I started from zero). No need to muck about with binary strings, though, since we have bitwise or and can work entirely in integers. At each step, generate the top half by reversing the previous sequence and adding the next bit.

sub gray {
  my $depth=shift;
  my @s=(0,1);
  if ($depth>1) {
    my $k=1;
    foreach (2..$depth) {
      $k*=2;
      my @o=@s;
      push @o,map {$_ | $k} reverse @s;
      @s=@o;
    }
  }
  return \@s;
}

Raku works the same way except for the obligatory mucking about with sequence flattening.

      map {push @o, $_ +| $k}, reverse @s.flat;